Here’s the script:

tell application id "com.apple.iTunes"
	try
		set sel to selection
		if sel is {} then error
		set opt to (display dialog "Make new playlist from selected tracks named:" default answer ¬
			"" with title "Name New Playlist From Selection" with icon 1)
		set newName to (text returned of opt)
		if newName is "" then error
	on error
		return
	end try

	set newPlaylist to (make new playlist with properties {name:newName})
	repeat with t in sel
		try
			duplicate t to newPlaylist
		end try
	end repeat
	reveal newPlaylist
end tell

I named it “Name New Playlist from Selection”, saved it to ~/Library/iTunes/Scripts/ and gave it the shortcut using these instructions.

You know there is.

I put together this script which uses a combination of standard AppleScripting and GUI Scripting to emulate Josh’s shortcuts solution:

tell application "iTunes" to activate
tell application "System Events"
	key code 11 using command down
	tell application "iTunes" to reveal track 1 of (get view of front window)
	key code 0 using {command down, shift down}
	key code 11 using command down
end tell

Save this as whatever you like—I call it “Column Browser Go Home”—save it to the ~/Library/iTunes/Scripts folder, and assign it a shortcut (make sure you have enabled GUI Scripting, too, as outlined in this article on using key codes). When launched after you’ve Column Browsed to a discrete set of tracks it will restore the entire list of tracks and jump to the top of the selected playlist. In my case this is usually the Music library playlist, but it will work with any playlist that’s being viewed with the Column Browser.

[UPDATE] And after all that, @tonyhazeldine tweets: “The same can be done by clicking on the column titles at the top of the column browser.” Yes, but each column has to be clicked.

tell application "iTunes"
	activate
	-- select the Music library
	reveal (some playlist whose special kind is Music)
end tell
tell application "System Events"
	-- bring focus to Search box - Command-Option-F
	key code 3 using {command down, option down}
end tell

I’ve given it a keyboard shortcut of Command-Option-S.

More information on AppleScripting iTunes with key codes and keystrokes is here.

But ANYway.

Correspondent Dirk Scharff noted that “if used in the first 2-20 seconds of the song the skip counter is increased too and that’s somewhat undesirable as this wouldn’t happen if I played that song.” I don’t pay much attention to skips at my house, but he has a point. So Dirk submitted a mod to the script which I have incorporated below:

The two lines that contain the originalSkipCount variable are Dirk’s mod:

tell application "iTunes"
	if player state is not stopped then
		try
			set theTrack to current track
			tell theTrack
				set originalSkipCount to (get skipped count)
				set played count to (get played count) + 1
				set played date to (get current date)
			end tell
			next track
			set theTrack's skipped count to originalSkipCount
		end try
	end if
end tell

This will keep the skip count from increasing under any circumstance (when you run the script, that is; it doesn’t change iTunes’ default skip-counting behavior). If you prefer that the skip counter behave normally you can just comment out or delete the two lines with originalSkipCount.

tell application "iTunes"
	if selection is {} then return
	set strm to (item 1 of selection)
	if (get class of strm) is not URL track then return
	repeat
		try
			play strm
			exit repeat
		on error m number n
			delay 15
		end try
	end repeat
end tell

The earlier script used the open location command, errors from which could not be defeated with the try block.