Apple Music Profile
YouTube Channel
RSS Feed
Dupin
Join Together
M3Unify
30 Most Recent RSS FeedDislike is a New iTunes 12.5 Track Property
If you have access to the latest macOS 10.12 Developer Preview then you probably downloaded the newest iTunes 12.5 beta (12.5.0.63). It has a new "Dislike" track feature and corresponding AppleScript disliked track and playlist property and album disliked track property. These work like the corresponding loved properties.
Except...
In the current iTunes beta there is no way to know which tracks you've Dislike'd; there's no column in the browser window [UPDATE: Yes there is], there's no widget in the Get Info window [UPDATE: Yes there is], and there's no "Disliked" criteria for Smart Playlist making—yet, I guess, right? [UPDATE: Right! iTunes 12.5.2, released October 28, 2016, has Love/Album Love criteria that incorporates "Disliked".]
But for now there is this:
-- iTunes 12.5.0.63 or later required
tell application "iTunes"
set dislikedTracks to {}
try
set dislikedTracks to every track of library playlist 1 whose disliked is true
end try
if dislikedTracks is {} then return
if (exists playlist "_Disliked_") then
delete playlist "_Disliked_"
end if
set thePlaylist to (make new playlist with properties ¬
{name:"_Disliked_", description:("Disliked tracks as of " & my makeDateString()) as text})
repeat with dislikedTrack in dislikedTracks
try
duplicate dislikedTrack to thePlaylist
end try
end repeat
reveal thePlaylist
end tell
to makeDateString()
set cd to (get current date)
return (short date string of cd & space & time string of cd) as text
end makeDateString
It just copies every disliked track to a new playlist named "_Disliked_", re-creating the playlist each time the script is run. It'll also time stamp the playlist's description.
This script won't work unless you have the latest iTunes 12.5 beta with the disliked track property, which I suspect may be in the next Public Beta release.
